home *** CD-ROM | disk | FTP | other *** search
/ Aminet 30 / Aminet 30 (1999)(Schatztruhe)[!][Apr 1999].iso / Gloom_3 / src / 060_1.s < prev    next >
Text File  |  1997-08-26  |  21KB  |  865 lines
  1.  
  2.         machine 68060
  3.  
  4. NEWCODE EQU 1
  5.  
  6.         bra.w    initc2p     ; offset 0: initialization routines
  7.         bra.w    doc2p_1X8    ; offset 4: one pixel wide version, AGA
  8.         bra.w    doc2p_1X6    ; offset 8: one pixel wide version, EHB
  9.         bra.w    doc2p_2X8    ; offset 12: two pixel wide version, AGA
  10.         bra.w    doc2p_2X6    ; offset 16: two pixel wide version, EHB
  11.         dc.l    string        ; offset 20: address of descr string
  12.  
  13.         dc.b    '$VER: 060_1 1.0 (26/8/97)',0
  14. string        dc.b    'A chunky to planar routine by Peter McGavin. '
  15.         dc.b    'Changes By Iain Barclay. '
  16.         dc.b    'Optimised for 68060. '
  17.         dc.b    'Supports 6/8 bitplane, single/double width pixels.',0
  18.         even
  19.  
  20. initc2p
  21.  
  22. ; create 2 tables for Gloom
  23.  
  24. ; a0=columns buffer to fill in (array of longs) for 1 wide pixs.
  25. ; a1=columns buffer for 2 wide pixs
  26. ; d0=how many columns (multiple of 32)
  27. ; a2=palette remapping array (do 256)
  28.  
  29.         move.w    #255,d1 ;#colours-1
  30. .loop        move.b    d1,(a2,d1.w)
  31.         dbf    d1,.loop
  32.  
  33. ; column offsets for 1 wide pixels
  34.  
  35. ; 0,2,4,6,8,10,12,14,1,3,5,7,9,11,13,15,
  36. ; 16,18,20,...
  37.  
  38.         move.l    d0,d4
  39.         lsr.w    #4,d4
  40.         subq.w    #1,d4
  41.         moveq    #0,d1
  42. .loop0        moveq    #1,d2
  43. .loop1        moveq    #7,d3
  44. .loop2        move.l    d1,(a0)+
  45.         addq.l    #2,d1
  46.         dbf    d3,.loop2
  47.         sub.l    #15,d1
  48.         dbf    d2,.loop1
  49.         add.l    #14,d1
  50.         dbf    d4,.loop0
  51.  
  52. ; column offsets for 2 wide pixels
  53.  
  54. ; 0,4,8,12,1,5,9,13,2,6,10,14,3,7,11,15,
  55. ; 16,20,24,28,17,...
  56.  
  57.         lsr.w    #4,d0
  58.         subq.w    #1,d0
  59.         moveq    #0,d1
  60. .loop3        moveq    #3,d2
  61. .loop4        moveq    #3,d3
  62. .loop5        move.l    d1,(a1)+
  63.         addq.l    #4,d1
  64.         dbf    d3,.loop5
  65.         sub.l    #15,d1
  66.         dbf    d2,.loop4
  67.         add.l    #12,d1
  68.         dbf    d0,.loop3
  69.         rts
  70.  
  71.         cnop    0,4
  72. doc2p_1X8
  73. ; inputs:
  74. ; a0.l=src chunky buffer
  75. ; a1.l=dest chipmem bitmap
  76. ; d0.w=width (in pixels - multiple of 32) to convert
  77. ; d1.w=height (in pixels - even)
  78. ; d2.l=modulo from one bitplane to next (copmod-ish)
  79. ; d3.l=modulo from start of one line to start of next (linemod)
  80.  
  81.         movea.l d2,a5        ; a5 = bpmod
  82.         lsr.w    #4,d0
  83.         lsl.l    #3,d2
  84.         ext.l    d0
  85.         sub.l    a5,d2
  86.         move.l    d0,d4
  87.         subq.l    #2,d2
  88.         subq.l    #1,d4
  89.         movea.l d2,a6        ; a6 = 7*bpmod-2
  90.  
  91.         move.l    d4,-(sp)    ; (4,sp) = num of 16 pix per row - 1
  92.  
  93.         add.l    d0,d0        ; num of 8 pix per row (bytesperrow)
  94.         move.w    d1,d7
  95.         sub.l    d0,d3
  96.         subq.w    #1,d7        ; d7 = height-1
  97.         sub.l    a6,d3
  98.         movea.l #$f0f0f0f0,a2    ; a2 = 4 bit mask
  99.         move.l    d3,-(sp)    ; (sp) = linemod-bytesperrow-7*bpmod+2
  100.  
  101.         movea.l #$cccccccc,a3    ; a3 = 2 bit mask
  102.         movea.l #$aaaa5555,a4    ; a4 = 1 bit mask
  103.         move.l    a2,d6        ; 4 bit mask = #$f0f0f0f0
  104.  
  105. ;------------------------------------------------------------------------
  106. ;
  107. ; 00        a7a6a5a4a3a2a1a0 i7i6i5i4i3i2i1i0 b7b6b5b4b3b2b1b0 j7j6j5j4j3j2j1j0
  108. ; 01        c7c6c5c4c3c2c1c0 k7k6k5k4k3k2k1k0 d7d6d5d4d3d2d1d0 l7l6l5l4l3l2l1l0
  109. ; 02        e7e6e5e4e3e2e1e0 m7m6m5m4m3m2m1m0 f7f6f5f4f3f2f1f0 n7n6n5n4n3n2n1n0
  110. ; 03        g7g6g5g4g3g2g1g0 o7o6o5o4o3o2o1o0 h7h6h5h4h3h2h1h0 p7p6p5p4p3p2p1p0
  111. ;
  112. ; 10 00x02a a7a6a5a4e7e6e5e4 i7i6i5i4m7m6m5m4 b7b6b5b4f7f6f5f4 j7j6j5j4n7n6n5n4
  113. ; 11 00x02b a3a2a1a0e3e2e1e0 i3i2i1i0m3m2m1m0 b3b2b1b0f3f2f1f0 j3j2j1j0n3n2n1n0
  114. ; 12 01x03a c7c6c5c4g7g6g5g4 k7k6k5k4o7o6o5o4 d7d6d5d4h7h6h5h4 l7l6l5l4p7p6p5p4
  115. ; 13 01x03b c3c2c1c0g3g2g1g0 k3k2k1k0o3o2o1o0 d3d2d1d0h3h2h1h0 l3l2l1l0p3p2p1p0
  116. ;
  117. ; 20 10x12a a7a6c7c6e7e6g7g6 i7i6k7k6m7m6o7o6 b7b6d7d6f7f6h7h6 j7j6l7l6n7n6p7p6
  118. ; 21 10x12b a5a4c5c4e5e4g5g4 i5i4k5k4m5m4o5o4 b5b4d5d4f5f4h5h4 j5j4l5l4n5n4p5p4
  119. ;
  120. ; 30 20x20  a7b7c7d7e7f7g7h7 i7j7k7l7m7n7o7p7 a6b6c6d6e6f6g6h6 i6j6k6l6m6n6o6p6
  121. ; 31 21x21  a5b5c5d5e5f5g5h5 i5j5k5l5m5n5o5p5 a4b4c4d4e4f4g4h4 i4j4k4l4m4n4o4p4
  122. ;
  123. ; 22 11x13a a3a2c3c2e3e2g3g2 i3i2k3k2m3m2o3o2 b3b2d3d2f3f2h3h2 j3j2l3l2n3n2p3p2
  124. ; 23 11x13b a1a0c1c0e1e0g1g0 i1i0k1k0m1m0o1o0 b1b0d1d0f1f0h1h0 j1j0l1l0n1n0p1p0
  125. ;
  126. ; 32 22x22  a3b3c3d3e3f3g3h3 i3j3k3l3m3n3o3p3 a2b2c2d2e2f2g2h2 i2j2k2l2m2n2o2p2
  127. ; 33 23x23  a1b1c1d1e1f1g1h1 i1j1k1l1m1n1o1p1 a0b0c0d0e0f0g0h0 i0j0k0l0m0n0o0p0
  128. ;
  129. ;------------------------------------------------------------------------
  130.  
  131.         swap    d7
  132.  
  133.         movem.l (a0)+,d0-d3    ; get first 4 pixels 00
  134.  
  135.         move.w    d4,d7        ; num 16 pix per row - 1
  136.         move.l    d0,d4
  137.         and.l    d6,d0
  138.         eor.l    d0,d4
  139.         lsl.l    #4,d4
  140.  
  141.         bra.b    .same_from_here
  142.  
  143.         cnop    0,4
  144.  
  145. .outerloop    swap    d7
  146.  
  147.         movem.l (a0)+,d0-d3    ; get 4 next pixels 00
  148.  
  149.         move.w    (6,sp),d7    ; num 16 pix per row - 1
  150.         move.l    d0,d4
  151.         move.w    d5,(a1)     ; 30 -> plane 6
  152.         and.l    d6,d0
  153.         adda.l    a5,a1        ; +bpmod
  154.         swap    d5
  155.         eor.l    d0,d4
  156.         move.w    d5,(a1)     ; 30 -> plane 7
  157.         lsl.l    #4,d4
  158.         adda.l    (sp),a1     ; +linemod-bytesperrow-7*bpmod+2
  159.         bra.b    .same_from_here
  160.  
  161.         cnop    0,4
  162. .innerloop    movem.l (a0)+,d0-d3    ; get 4 next pixels 00
  163.  
  164.         move.w    d5,(a1)     ; 30 -> plane 6
  165.         move.l    d0,d4
  166.         adda.l    a5,a1        ; +bpmod
  167.         and.l    d6,d0
  168.         swap    d5
  169.         eor.l    d0,d4
  170.         move.w    d5,(a1)     ; 30 -> plane 7
  171.         lsl.l    #4,d4
  172.         suba.l    a6,a1        ; - 7 * bpmod + 2
  173.  
  174. .same_from_here move.l    d2,d5
  175.         and.l    d6,d5
  176.         eor.l    d5,d2
  177.         lsr.l    #4,d5
  178.         or.l    d4,d2        ; 00x02 -> 10 11
  179.         or.l    d5,d0
  180.         move.l    d1,d4
  181.         move.l    d3,d5
  182.         and.l    d6,d1
  183.         and.l    d6,d5
  184.         eor.l    d1,d4
  185.         eor.l    d5,d3
  186.         lsl.l    #4,d4
  187.         lsr.l    #4,d5
  188.         or.l    d4,d3        ; 01x03 -> 12 13
  189.         or.l    d5,d1
  190.         move.l    a3,d6        ; 2 bit mask = #$cccccccc
  191.         move.l    d2,d4
  192.         move.l    d3,d5
  193.         and.l    d6,d2
  194.         and.l    d6,d5
  195.         eor.l    d2,d4
  196.         eor.l    d5,d3
  197.         lsl.l    #2,d4
  198.         move.l    a4,d6        ; 1 bit mask = #$aaaa5555
  199.         or.l    d4,d3        ; 11x13b -> 23
  200.         move.l    d3,d4
  201.         and.l    d6,d3
  202.         eor.l    d3,d4
  203.         lsr.w    #1,d4
  204.         swap    d4
  205.         add.w    d4,d4
  206.         or.l    d4,d3        ; 23x23 -> 33
  207.  
  208.         move.w    d3,(a1)     ; 33 -> plane 0
  209.         lsr.l    #2,d5
  210.         adda.l    a5,a1        ; +bpmod
  211.         or.l    d5,d2        ; 11x13a -> 22
  212.         swap    d3
  213.         move.l    d2,d4
  214.         move.w    d3,(a1)     ; 33 -> plane 1
  215.         and.l    d6,d2
  216.         adda.l    a5,a1        ; +bpmod
  217.         eor.l    d2,d4
  218.         move.l    a3,d6        ; 2 bit mask = #$cccccccc
  219.         lsr.w    #1,d4
  220.         swap    d4
  221.         add.w    d4,d4
  222.         or.l    d4,d2        ; 22x22 -> 32
  223.         move.l    d0,d4
  224.         move.w    d2,(a1)     ; 32 -> plane 2
  225.         and.l    d6,d0
  226.         adda.l    a5,a1        ; +bpmod
  227.         move.l    d1,d5
  228.         eor.l    d0,d4
  229.         and.l    d6,d5
  230.         lsl.l    #2,d4
  231.         eor.l    d5,d1
  232.         move.l    a4,d6        ; 1 bit mask = #$aaaa5555
  233.         or.l    d4,d1        ; 10x12b -> 21
  234.         swap    d2
  235.         move.l    d1,d4
  236.         move.w    d2,(a1)     ; 32 -> plane 3
  237.         and.l    d6,d1
  238.         adda.l    a5,a1        ; +bpmod
  239.         eor.l    d1,d4
  240.         lsr.l    #2,d5
  241.         lsr.w    #1,d4
  242.         or.l    d5,d0        ; 10x12a -> 20
  243.         swap    d4
  244.         move.l    d0,d5
  245.         add.w    d4,d4
  246.         and.l    d6,d0
  247.         or.l    d4,d1        ; 21x21 -> 31
  248.         eor.l    d0,d5
  249.         move.w    d1,(a1)     ; 31 -> plane 4
  250.         lsr.w    #1,d5
  251.         adda.l    a5,a1        ; +bpmod
  252.         swap    d1
  253.         swap    d5
  254.         move.w    d1,(a1)     ; 31 -> plane 5
  255.         add.w    d5,d5
  256.         adda.l    a5,a1        ; +bpmod
  257.         or.l    d0,d5        ; 20x20 -> 30
  258.         move.l    a2,d6        ; 4 bit mask = #$f0f0f0f0
  259.         dbra    d7,.innerloop
  260.         swap    d7
  261.         dbra    d7,.outerloop
  262.         move.w    d5,(a1)     ; 30 -> plane 6
  263.         adda.l    a5,a1        ; +bpmod
  264.         swap    d5
  265.         move.w    d5,(a1)     ; 30 -> plane 7
  266.         addq.l    #8,sp        ; remove locals
  267.         rts
  268.  
  269.         cnop    0,4
  270. doc2p_1X6
  271. ; inputs:
  272. ; a0.l=src chunky buffer
  273. ; a1.l=dest chipmem bitmap
  274. ; d0.w=width (in pixels - multiple of 32) to convert
  275. ; d1.w=height (in pixels - even)
  276. ; d2.l=modulo from one bitplane to next (copmod-ish)
  277. ; d3.l=modulo from start of one line to start of next (linemod)
  278.  
  279.         movea.l d2,a5        ; a5 = bpmod
  280.         lsl.l    #2,d2
  281.         add.l    a5,d2
  282.         subq.l    #2,d2
  283.         movea.l d2,a6        ; a6 = 5*bpmod-2
  284.  
  285.         lsr.w    #4,d0
  286.         ext.l    d0
  287.         move.l    d0,d4
  288.         subq.l    #1,d4
  289.         move.l    d4,-(sp)    ; (4,sp) = num of 16 pix per row - 1
  290.  
  291.         add.l    d0,d0        ; num of 8 pix per row (bytesperrow)
  292.         sub.l    d0,d3
  293.         sub.l    a6,d3
  294.         move.l    d3,-(sp)    ; (sp) = linemod-bytesperrow-5*bpmod+2
  295.  
  296.         move.w    d1,d7
  297.         subq.w    #1,d7        ; d7 = height-1
  298.  
  299.         movea.l #$f0f0f0f0,a2    ; a2 = 4 bit mask
  300.         movea.l #$cccccccc,a3    ; a3 = 2 bit mask
  301.         movea.l #$aaaa5555,a4    ; a4 = 1 bit mask
  302.         move.l    a2,d6        ; 4 bit mask = #$f0f0f0f0
  303.  
  304. ;------------------------------------------------------------------------
  305. ;
  306. ; 00        ....a5a4a3a2a1a0 ....i5i4i3i2i1i0 ....b5b4b3b2b1b0 ....j5j4j3j2j1j0
  307. ; 01        ....c5c4c3c2c1c0 ....k5k4k3k2k1k0 ....d5d4d3d2d1d0 ....l5l4l3l2l1l0
  308. ; 02        ....e5e4e3e2e1e0 ....m5m4m3m2m1m0 ....f5f4f3f2f1f0 ....n5n4n3n2n1n0
  309. ; 03        ....g5g4g3g2g1g0 ....o5o4o3o2o1o0 ....h5h4h3h2h1h0 ....p5p4p3p2p1p0
  310. ;
  311. ; 10 00x02a ....a5a4....e5e4 ....i5i4....m5m4 ....b5b4....f5f4 ....j5j4....n5n4
  312. ; 11 00x02b a3a2a1a0e3e2e1e0 i3i2i1i0m3m2m1m0 b3b2b1b0f3f2f1f0 j3j2j1j0n3n2n1n0
  313. ; 12 01x03a ....c5c4....g5g4 ....k5k4....o5o4 ....d5d4....h5h4 ....l5l4....p5p4
  314. ; 13 01x03b c3c2c1c0g3g2g1g0 k3k2k1k0o3o2o1o0 d3d2d1d0h3h2h1h0 l3l2l1l0p3p2p1p0
  315. ;
  316. ; 21 10x12b a5a4c5c4e5e4g5g4 i5i4k5k4m5m4o5o4 b5b4d5d4f5f4h5h4 j5j4l5l4n5n4p5p4
  317. ;
  318. ; 31 21x21  a5b5c5d5e5f5g5h5 i5j5k5l5m5n5o5p5 a4b4c4d4e4f4g4h4 i4j4k4l4m4n4o4p4
  319. ;
  320. ; 22 11x13a a3a2c3c2e3e2g3g2 i3i2k3k2m3m2o3o2 b3b2d3d2f3f2h3h2 j3j2l3l2n3n2p3p2
  321. ; 23 11x13b a1a0c1c0e1e0g1g0 i1i0k1k0m1m0o1o0 b1b0d1d0f1f0h1h0 j1j0l1l0n1n0p1p0
  322. ;
  323. ; 32 22x22  a3b3c3d3e3f3g3h3 i3j3k3l3m3n3o3p3 a2b2c2d2e2f2g2h2 i2j2k2l2m2n2o2p2
  324. ; 33 23x23  a1b1c1d1e1f1g1h1 i1j1k1l1m1n1o1p1 a0b0c0d0e0f0g0h0 i0j0k0l0m0n0o0p0
  325. ;
  326. ;------------------------------------------------------------------------
  327.  
  328.         swap    d7
  329.         move.w    d4,d7        ; num 16 pix per row - 1
  330.  
  331.         movem.l (a0)+,d0-d3    ; get first 4 pixels 00
  332.  
  333.         move.l    d0,d4
  334.         and.l    d6,d0
  335.         eor.l    d0,d4
  336.         lsl.l    #4,d4
  337.  
  338.         bra.b    .same_from_here
  339.  
  340.         cnop    0,4
  341.  
  342. .outerloop    swap    d7
  343.         move.w    (6,sp),d7    ; num 16 pix per row - 1
  344.  
  345.         movem.l (a0)+,d0-d3    ; get 4 next pixels 00
  346.  
  347.         move.w    d5,(a1)     ; 31 -> plane 4
  348.         adda.l    a5,a1        ; +bpmod
  349.  
  350.         move.l    d0,d4
  351.         and.l    d6,d0
  352.         eor.l    d0,d4
  353.         lsl.l    #4,d4
  354.  
  355.         swap    d5
  356.         move.w    d5,(a1)     ; 31 -> plane 5
  357.         adda.l    (sp),a1     ; +linemod-bytesperrow-5*bpmod+2
  358.  
  359.         bra.b    .same_from_here
  360.  
  361.         cnop    0,4
  362. .innerloop    movem.l (a0)+,d0-d3    ; get 4 next pixels 00
  363.  
  364.         move.w    d5,(a1)     ; 31 -> plane 4
  365.         adda.l    a5,a1        ; +bpmod
  366.  
  367.         move.l    d0,d4
  368.         and.l    d6,d0
  369.         eor.l    d0,d4
  370.         lsl.l    #4,d4
  371.  
  372.         swap    d5
  373.         move.w    d5,(a1)     ; 31 -> plane 5
  374.         suba.l    a6,a1        ; -5*bpmod+2
  375.  
  376. .same_from_here move.l    d2,d5
  377.         and.l    d6,d5
  378.         eor.l    d5,d2
  379.         lsr.l    #4,d5
  380.         or.l    d5,d0
  381.         or.l    d4,d2        ; 00x02 -> 10 11
  382.         move.l    d1,d4
  383.         and.l    d6,d1
  384.         eor.l    d1,d4
  385.         move.l    d3,d5
  386.         and.l    d6,d5
  387.         eor.l    d5,d3
  388.         lsr.l    #4,d5
  389.         lsl.l    #4,d4
  390.         or.l    d5,d1
  391.         or.l    d4,d3        ; 01x03 -> 12 13
  392.         move.l    a3,d6        ; 2 bit mask = #$cccccccc
  393.         move.l    d2,d4
  394.         and.l    d6,d2
  395.         eor.l    d2,d4
  396.         move.l    d3,d5
  397.         and.l    d6,d5
  398.         eor.l    d5,d3
  399.         lsl.l    #2,d4
  400.         or.l    d4,d3        ; 11x13b -> 23
  401.         move.l    a4,d6        ; 1 bit mask = #$aaaa5555
  402.         move.l    d3,d4
  403.         and.l    d6,d3
  404.         eor.l    d3,d4
  405.         lsr.w    #1,d4
  406.         swap    d4
  407.         add.w    d4,d4
  408.         or.l    d4,d3        ; 23x23 -> 33
  409.  
  410.         move.w    d3,(a1)     ; 33 -> plane 0
  411.         adda.l    a5,a1        ; +bpmod
  412.  
  413.         lsr.l    #2,d5
  414.         or.l    d5,d2        ; 11x13a -> 22
  415.         move.l    d2,d4
  416.         and.l    d6,d2
  417.         eor.l    d2,d4
  418.  
  419.         swap    d3
  420.         move.w    d3,(a1)     ; 33 -> plane 1
  421.         adda.l    a5,a1        ; +bpmod
  422.  
  423.         lsr.w    #1,d4
  424.         swap    d4
  425.         add.w    d4,d4
  426.         or.l    d4,d2        ; 22x22 -> 32
  427.         lsl.l    #2,d0
  428.  
  429.         move.w    d2,(a1)     ; 32 -> plane 2
  430.         adda.l    a5,a1        ; +bpmod
  431.  
  432.         or.l    d0,d1        ; 10x12b -> 21
  433.         swap    d2
  434.         move.l    d1,d5
  435.         and.l    d6,d1
  436.         eor.l    d1,d5
  437.  
  438.         move.w    d2,(a1)     ; 32 -> plane 3
  439.         adda.l    a5,a1        ; +bpmod
  440.  
  441.         lsr.w    #1,d5
  442.         swap    d5
  443.         add.w    d5,d5
  444.         or.l    d1,d5        ; 21x21 -> 31
  445.         move.l    a2,d6        ; 4 bit mask = #$f0f0f0f0
  446.  
  447.         dbra    d7,.innerloop
  448.  
  449.         swap    d7
  450.         dbra    d7,.outerloop
  451.  
  452.         move.w    d5,(a1)     ; 31 -> plane 4
  453.         adda.l    a5,a1        ; +bpmod
  454.         swap    d5
  455.         move.w    d5,(a1)     ; 31 -> plane 5
  456.         addq.l    #8,sp        ; remove locals
  457.         rts
  458.  
  459.         cnop    0,4
  460. doc2p_2X8
  461. ; inputs:
  462. ; a0.l=src chunky buffer
  463. ; a1.l=dest chipmem bitmap
  464. ; d0.w=width (in pixels - multiple of 32) to convert
  465. ; d1.w=height (in pixels - even)
  466. ; d2.l=modulo from one bitplane to next (copmod-ish)
  467. ; d3.l=modulo from start of one line to start of next (linemod)
  468.  
  469.         movea.l d2,a6        ; a6 = bpmod
  470.         move.l    d2,d4
  471.         lsl.l    #3,d4
  472.         sub.l    d2,d4
  473.         neg.l    d4
  474.         addq.l    #4,d4
  475.         movea.l d4,a3        ; a3 = -7*bpmod+4
  476.         movea.l d4,a4        ; a4 = -7*bpmod+4
  477.         lsr.w    #4,d0
  478.         movea.w d0,a2
  479.         subq.l    #1,a2        ; a2 = num 16 pix per row - 1
  480.         lsl.w    #2,d0        ; d0 = num 4 pix per row (bytesperrow)
  481.         movea.l d3,a5
  482.         suba.w    d0,a5
  483.         adda.l    a3,a5        ; a5 = linemod-bytesperrow-7*bpmod+4
  484.         move.w    d1,d7
  485.         subq.w    #1,d7        ; d7 = height - 1
  486.  
  487. ;------------------------------------------------------------------------
  488. ; original pixels
  489. ; 00        a7a6a5a4a3a2a1a0 e7e6e5e4e3e2e1e0 i7i6i5i4i3i2i1i0 m7m6m5m4m3m2m1m0
  490. ; 01        b7b6b5b4b3b2b1b0 f7f6f5f4f3f2f1f0 j7j6j5j4j3j2j1j0 n7n6n5n4n3n2n1n0
  491. ; 02        c7c6c5c4c3c2c1c0 g7g6g5g4g3g2g1g0 k7k6k5k4k3k2k1k0 o7o6o5o4o3o2o1o0
  492. ; 03        d7d6d5d4d3d2d1d0 h7h6h5h4h3h2h1h0 l7l6l5l4l3l2l1l0 p7p6p5p4p3p2p1p0
  493. ;
  494. ; after 4bit merge
  495. ; 10 00x02a a7a6a5a4c7c6c5c4 e7e6e5e4g7g6g5g4 i7i6i5i4k7k6k5k4 m7m6m5m4o7o6o5o4
  496. ; 11 00x02b a3a2a1a0c3c2c1c0 e3e2e1e0g3g2g1g0 i3i2i1i0k3k2k1k0 m3m2m1m0o3o2o1o0
  497. ; 12 01x03a b7b6b5b4d7d6d5d4 f7f6f5f4h7h6h5h4 j7j6j5j4l7l6l5l4 n7n6n5n4p7p6p5p4
  498. ; 13 01x03b b3b2b1b0d3d2d1d0 f3f2f1f0h3h2h1h0 j3j2j1j0l3l2l1l0 n3n2n1n0p3p2p1p0
  499. ;
  500. ; after 2bit merge
  501. ; 20 10x12a a7a6b7b6c7c6d7d6 e7e6f7f6g7g6h7h6 i7i6j7j6k7k6l7l6 m7m6n7n6o7o6p7p6
  502. ; 21 10x12b a5a4b5b4c5c4d5d4 e5e4f5f4g5g4h5h4 i5i4j5j4k5k4l5l4 m5m4n5n4o5o4p5p4
  503. ; 22 11x13a a3a2b3b2c3c2d3d2 e3e2f3f2g3g2h3h2 i3i2j3j2k3k2l3l2 m3m2n3n2o3o2p3p2
  504. ; 23 11x13b a1a0b1b0c1c0d1d0 e1e0f1f0g1g0h1h0 i1i0j1j0k1k0l1l0 m1m0n1n0o1o0p1p0
  505. ;
  506. ; after 1bit merge
  507. ; 30 20x20a a7a7b7b7c7c7d7d7 e7e7f7f7g7g7h7h7 i7i7j7j7k7k7l7l7 m7m7n7n7o7o7p7p7
  508. ; 31 20x20b a6a6b6b6c6c6d6d6 e6e6f6f6g6g6h6h6 i6i6j6j6k6k6l6l6 m6m6n6n6o6o6p6p6
  509. ; 32 21x21a a5a5b5b5c5c5d5d5 e5e5f5f5g5g5h5h5 i5i5j5j5k5k5l5l5 m5m5n5n5o5o5p5p5
  510. ; 33 21x21b a4a4b4b4c4c4d4d4 e4e4f4f4g4g4h4h4 i4i4j4j4k4k4l4l4 m4m4n4n4o4o4p4p4
  511. ; 34 22x22a a3a3b3b3c3c3d3d3 e3e3f3f3g3g3h3h3 i3i3j3j3k3k3l3l3 m3m3n3n3o3o3p3p3
  512. ; 35 22x22b a2a2b2b2c2c2d2d2 e2e2f2f2g2g2h2h2 i2i2j2j2k2k2l2l2 m2m2n2n2o2o2p2p2
  513. ; 36 23x23a a1a1b1b1c1c1d1d1 e1e1f1f1g1g1h1h1 i1i1j1j1k1k1l1l1 m1m1n1n1o1o1p1p1
  514. ; 37 23x23b a0a0b0b0c0c0d0d0 e0e0f0f0g0g0h0h0 i0i0j0j0k0k0l0l0 m0m0n0n0o0o0p0p0
  515. ;------------------------------------------------------------------------
  516.  
  517.         swap    d7
  518.         move.w    a2,d7        ; number of 16 (game) pixels per row - 1
  519.  
  520.         movem.l (a0)+,d0-d2    ; read first 12 (game) pixels
  521.         move.l    #$f0f0f0f0,d6
  522.  
  523.         move.l    d0,d4
  524.         move.l    d2,d5
  525.         and.l    d6,d0        ; #$f0f0f0f0
  526.         eor.l    d0,d4
  527.         lsl.l    #4,d4
  528.         and.l    d6,d5        ; #$f0f0f0f0
  529.         eor.l    d5,d2
  530.         lsr.l    #4,d5
  531.         or.l    d5,d0
  532.         or.l    d4,d2        ; 00x02 -> 10 11
  533.  
  534.         bra    .same_from_here
  535.  
  536.         cnop    0,4
  537.  
  538. .outerloop    swap    d7
  539.         move.w    a2,d7        ; number of 16 (game) pixels per row - 1
  540.  
  541. .innerloop    movem.l (a0)+,d0-d2    ; read next 12 (game) pixels
  542.         move.l    d6,(a1)     ; 32 -> plane 5
  543.         adda.l    a6,a1        ; +bpmod
  544.  
  545.         move.l    #$f0f0f0f0,d6
  546.  
  547.         move.l    d0,d4
  548.         and.l    d6,d0        ; #$f0f0f0f0
  549.         eor.l    d0,d4
  550.         lsl.l    #4,d4
  551.  
  552.         move.l    d5,(a1)     ; 31 -> plane 6
  553.         adda.l    a6,a1        ; +bpmod
  554.  
  555.         move.l    d2,d5
  556.         and.l    d6,d5        ; #$f0f0f0f0
  557.         eor.l    d5,d2
  558.         lsr.l    #4,d5
  559.         or.l    d5,d0
  560.         or.l    d4,d2        ; 00x02 -> 10 11
  561.  
  562.         move.l    d3,(a1)     ; 30 -> plane 7
  563.         adda.l    a4,a1        ; -7*bpmod+4 or
  564.                     ; +linemod-bytesperrow-7*bpmod+4
  565.  
  566. .same_from_here move.l    d1,d4
  567.         and.l    d6,d1        ; #$f0f0f0f0
  568.         eor.l    d1,d4
  569.         lsl.l    #4,d4
  570.  
  571.         move.l    (a0)+,d3    ; read next 4 (game) pixels
  572.  
  573.         move.l    d3,d5
  574.         and.l    d6,d5        ; #$f0f0f0f0
  575.         eor.l    d5,d3
  576.         lsr.l    #4,d5
  577.         or.l    d5,d1
  578.         or.l    d4,d3        ; 01x03 -> 12 13
  579.  
  580.         move.l    #$cccccccc,d6
  581.  
  582.         move.l    d0,d4
  583.         and.l    d6,d0        ; #$cccccccc
  584.         eor.l    d0,d4
  585.         lsl.l    #2,d4
  586.         move.l    d1,d5
  587.         and.l    d6,d5        ; #$cccccccc
  588.         eor.l    d5,d1
  589.         lsr.l    #2,d5
  590.         or.l    d5,d0
  591.         or.l    d4,d1        ; 10x12 -> 20 21
  592.  
  593.         move.l    d2,d4
  594.         and.l    d6,d2        ; #$cccccccc
  595.         eor.l    d2,d4
  596.         lsl.l    #2,d4
  597.         move.l    d3,d5
  598.         and.l    d6,d5        ; #$cccccccc
  599.         eor.l    d5,d3
  600.         lsr.l    #2,d5
  601.         or.l    d5,d2
  602.         or.l    d4,d3        ; 11x13 -> 22 23
  603.  
  604.         move.l    #$aaaaaaaa,d6
  605.  
  606.         move.l    d3,d4
  607.         and.l    d6,d3        ; #$aaaaaaaa
  608.         eor.l    d3,d4
  609.  
  610.         move.l    d4,d5
  611.         add.l    d4,d4
  612.         or.l    d4,d5        ; 23x23b -> 37
  613.  
  614.         move.l    d5,(a1)     ; 37 -> plane 0
  615.         adda.l    a6,a1        ; +bpmod
  616.  
  617.         move.l    d3,d4
  618.         lsr.l    #1,d3
  619.         or.l    d3,d4        ; 23x23a -> 36
  620.         move.l    d2,d5
  621.         and.l    d6,d2        ; #$aaaaaaaa
  622.         eor.l    d2,d5
  623.  
  624.         move.l    d4,(a1)     ; 36 -> plane 1
  625.         adda.l    a6,a1        ; +bpmod
  626.  
  627.         move.l    d5,d3
  628.         add.l    d5,d5
  629.         or.l    d5,d3        ; 22x22b -> 35
  630.         move.l    d2,d5
  631.         lsr.l    #1,d2
  632.         or.l    d5,d2        ; 22x22a -> 34
  633.  
  634.         move.l    d3,(a1)     ; 35 -> plane 2
  635.         adda.l    a6,a1        ; +bpmod
  636.  
  637.         move.l    d1,d4
  638.         and.l    d6,d1        ; #$aaaaaaaa
  639.         eor.l    d1,d4
  640.         move.l    d0,d5
  641.         and.l    d6,d0        ; #$aaaaaaaa
  642.         eor.l    d0,d5
  643.  
  644.         move.l    d2,(a1)     ; 34 -> plane 3
  645.         adda.l    a6,a1        ; +bpmod
  646.  
  647.         move.l    d4,d2
  648.         add.l    d4,d4
  649.         or.l    d4,d2        ; 21x21b -> 33
  650.         move.l    d1,d6
  651.         lsr.l    #1,d1
  652.         or.l    d1,d6        ; 21x21a -> 32
  653.         move.l    d5,d3
  654.  
  655.         move.l    d2,(a1)     ; 33 -> plane 4
  656.         adda.l    a6,a1        ; +bpmod
  657.  
  658.         add.l    d5,d5
  659.         or.l    d3,d5        ; 20x20b -> 31
  660.         move.l    d0,d3
  661.         lsr.l    #1,d0
  662.         or.l    d0,d3        ; 20x20a -> 30
  663.  
  664.         movea.l a3,a4        ; a4 = -7*bpmod+4
  665.  
  666.         dbra    d7,.innerloop
  667.  
  668.         movea.l a5,a4        ; a4 = linemod-bytesperrow-7*bpmod+4
  669.  
  670.         swap    d7
  671.         dbra    d7,.outerloop
  672.  
  673.         move.l    d6,(a1)     ; 32 -> plane 5
  674.         adda.l    a6,a1        ; +bpmod
  675.         move.l    d5,(a1)     ; 31 -> plane 6
  676.         adda.l    a6,a1        ; +bpmod
  677.         move.l    d3,(a1)     ; 30 -> plane 7
  678.         rts
  679.  
  680.         cnop    0,4
  681. doc2p_2X6
  682. ; inputs:
  683. ; a0.l=src chunky buffer
  684. ; a1.l=dest chipmem bitmap
  685. ; d0.w=width (in pixels - multiple of 32) to convert
  686. ; d1.w=height (in pixels - even)
  687. ; d2.l=modulo from one bitplane to next (copmod-ish)
  688. ; d3.l=modulo from start of one line to start of next (linemod)
  689.  
  690.         movea.l d2,a6        ; a6 = bpmod
  691.         move.l    d2,d4
  692.         lsl.l    #2,d4
  693.         add.l    d2,d4
  694.         neg.l    d4
  695.         addq.l    #4,d4
  696.         movea.l d4,a3        ; a3 = -5*bpmod+4
  697.         movea.l d4,a4        ; a4 = -5*bpmod+4
  698.         lsr.w    #4,d0
  699.         movea.w d0,a2
  700.         subq.l    #1,a2        ; a2 = num 16 pix per row - 1
  701.         lsl.w    #2,d0        ; d0 = num 4 pix per row (bytesperrow)
  702.         movea.l d3,a5
  703.         suba.w    d0,a5
  704.         adda.l    a3,a5        ; a5 = linemod-bytesperrow-5*bpmod+4
  705.         move.w    d1,d7
  706.         subq.w    #1,d7        ; d7 = height - 1
  707.  
  708. ;------------------------------------------------------------------------
  709. ; original pixels
  710. ; 00        ....a5a4a3a2a1a0 ....e5e4e3e2e1e0 ....i5i4i3i2i1i0 ....m5m4m3m2m1m0
  711. ; 01        ....b5b4b3b2b1b0 ....f5f4f3f2f1f0 ....j5j4j3j2j1j0 ....n5n4n3n2n1n0
  712. ; 02        ....c5c4c3c2c1c0 ....g5g4g3g2g1g0 ....k5k4k3k2k1k0 ....o5o4o3o2o1o0
  713. ; 03        ....d5d4d3d2d1d0 ....h5h4h3h2h1h0 ....l5l4l3l2l1l0 ....p5p4p3p2p1p0
  714. ;
  715. ; after 4bit merge
  716. ; 10 00x02a ....a5a4....c5c4 ....e5e4....g5g4 ....i5i4....k5k4 ....m5m4....o5o4
  717. ; 11 00x02b a3a2a1a0c3c2c1c0 e3e2e1e0g3g2g1g0 i3i2i1i0k3k2k1k0 m3m2m1m0o3o2o1o0
  718. ; 12 01x03a ....b5b4....d5d4 ....f5f4....h5h4 ....j5j4....l5l4 ....n5n4....p5p4
  719. ; 13 01x03b b3b2b1b0d3d2d1d0 f3f2f1f0h3h2h1h0 j3j2j1j0l3l2l1l0 n3n2n1n0p3p2p1p0
  720. ;
  721. ; after 2bit merge
  722. ; 21 10x12b a5a4b5b4c5c4d5d4 e5e4f5f4g5g4h5h4 i5i4j5j4k5k4l5l4 m5m4n5n4o5o4p5p4
  723. ; 22 11x13a a3a2b3b2c3c2d3d2 e3e2f3f2g3g2h3h2 i3i2j3j2k3k2l3l2 m3m2n3n2o3o2p3p2
  724. ; 23 11x13b a1a0b1b0c1c0d1d0 e1e0f1f0g1g0h1h0 i1i0j1j0k1k0l1l0 m1m0n1n0o1o0p1p0
  725. ;
  726. ; after 1bit merge
  727. ; 32 21x21a a5a5b5b5c5c5d5d5 e5e5f5f5g5g5h5h5 i5i5j5j5k5k5l5l5 m5m5n5n5o5o5p5p5
  728. ; 33 21x21b a4a4b4b4c4c4d4d4 e4e4f4f4g4g4h4h4 i4i4j4j4k4k4l4l4 m4m4n4n4o4o4p4p4
  729. ; 34 22x22a a3a3b3b3c3c3d3d3 e3e3f3f3g3g3h3h3 i3i3j3j3k3k3l3l3 m3m3n3n3o3o3p3p3
  730. ; 35 22x22b a2a2b2b2c2c2d2d2 e2e2f2f2g2g2h2h2 i2i2j2j2k2k2l2l2 m2m2n2n2o2o2p2p2
  731. ; 36 23x23a a1a1b1b1c1c1d1d1 e1e1f1f1g1g1h1h1 i1i1j1j1k1k1l1l1 m1m1n1n1o1o1p1p1
  732. ; 37 23x23b a0a0b0b0c0c0d0d0 e0e0f0f0g0g0h0h0 i0i0j0j0k0k0l0l0 m0m0n0n0o0o0p0p0
  733. ;------------------------------------------------------------------------
  734.  
  735.         swap    d7
  736.         move.w    a2,d7        ; number of 16 (game) pixels per row - 1
  737.         movem.l (a0)+,d0-d2    ; read first 12 (game) pixels
  738.         move.l    #$f0f0f0f0,d6
  739.         move.l    d0,d4
  740.         move.l    d2,d5
  741.         and.l    d6,d0        ; #$f0f0f0f0
  742.         eor.l    d0,d4
  743.         lsl.l    #4,d4
  744.         and.l    d6,d5        ; #$f0f0f0f0
  745.         eor.l    d5,d2
  746.         lsr.l    #4,d5
  747.         or.l    d5,d0
  748.         or.l    d4,d2        ; 00x02 -> 10 11
  749.  
  750.         move.l    d1,d4
  751.         and.l    d6,d1
  752.         eor.l    d1,d4
  753.         lsl.l    #4,d4
  754.         move.l    (a0)+,d3    ; read next 4
  755.         move.l    d3,d5
  756.         and.l    d6,d5
  757.         eor.l    d5,d3
  758.         lsr.l    #4,d5
  759.         or.l    d5,d1
  760.         or.l    d4,d3
  761.         lsl.l    #2,d0
  762.         or.l    d0,d1
  763.         move.l    d2,d4
  764.         move.l    #$cccccccc,d6
  765.         and.l    d6,d2
  766.         eor.l    d2,d4
  767.         lsl.l    #2,d4
  768.         bra    .same_from_here
  769.  
  770.         cnop    0,4
  771.  
  772. .outerloop    swap    d7
  773.         move.w    a2,d7        ; number of 16 (game) pixels per row - 1
  774.  
  775. .innerloop    movem.l (a0)+,d0-d2    ; read next 12 (game) pixels
  776.         move.l    d5,(a1)     ; 34 -> plane 3
  777.         adda.l    a6,a1        ; +bpmod
  778.         move.l    #$f0f0f0f0,d6
  779.         move.l    d0,d4
  780.         and.l    d6,d0
  781.         eor.l    d0,d4
  782.         lsl.l    #4,d4
  783.         move.l    d2,d5
  784.         and.l    d6,d5
  785.         eor.l    d5,d2
  786.         lsr.l    #4,d5
  787.         or.l    d5,d0
  788.         or.l    d4,d2
  789.         move.l    d1,d4
  790.         and.l    d6,d1
  791.         move.l    d3,(a1)     ; 33 -> plane 4
  792.         adda.l    a6,a1        ; +bpmod
  793.         eor.l    d1,d4
  794.         lsl.l    #4,d4
  795.         move.l    (a0)+,d3
  796.         move.l    d3,d5
  797.         and.l    d6,d5
  798.         eor.l    d5,d3
  799.         lsr.l    #4,d5
  800.         or.l    d5,d1
  801.         or.l    d4,d3
  802.         lsl.l    #2,d0
  803.         or.l    d0,d1
  804.         move.l    d2,d4
  805.         move.l    #$cccccccc,d6
  806.         and.l    d6,d2
  807.         eor.l    d2,d4
  808.         lsl.l    #2,d4
  809.         move.l    d6,(a1)
  810.         adda.l    a4,a1
  811. .same_from_here
  812.         move.l    d3,d5
  813.         and.l    d6,d5
  814.         eor.l    d5,d3
  815.         lsr.l    #2,d5
  816.         or.l    d5,d2
  817.         or.l    d4,d3
  818.         move.l    d3,d4
  819.         move.l    #$aaaaaaaa,d6
  820.         and.l    d6,d3
  821.         eor.l    d3,d4
  822.         move.l    d4,d5
  823.         add.l    d4,d4
  824.         or.l    d4,d5
  825.         move.l    d5,(a1)
  826.         adda.l    a6,a1
  827.         move.l    d3,d4
  828.         lsr.l    #1,d3
  829.         or.l    d3,d4
  830.         move.l    d2,d5
  831.         and.l    d6,d2
  832.         eor.l    d2,d5
  833.         move.l    d5,d6
  834.         add.l    d5,d5
  835.         move.l    d4,(a1)
  836.         adda.l    a6,a1
  837.         or.l    d5,d6
  838.         move.l    d2,d5
  839.         lsr.l    #1,d2
  840.         or.l    d2,d5
  841.         move.l    d1,d4
  842.         and.l    #$aaaaaaaa,d1
  843.         eor.l    d1,d4
  844.         move.l    d4,d3
  845.         move.l    d6,(a1)
  846.         adda.l    a6,a1
  847.         add.l    d4,d4
  848.         or.l    d4,d3
  849.         move.l    d1,d6
  850.         lsr.l    #1,d6
  851.         or.l    d1,d6
  852.         move.l    a3,a4
  853.         dbra    d7,.innerloop
  854.         move.l    a5,a4
  855.         swap    d7
  856.         dbra    d7,.outerloop
  857.         move.l    d5,(a1)
  858.         adda.l    a6,a1
  859.         move.l    d3,(a1)
  860.         adda.l    a6,a1
  861.         move.l    d6,(a1)
  862.         rts
  863.  
  864.         end
  865.